Ἐπιτέλους αὐτὸ τὸ ἔργο ἐξελίσσεται στὸ «ὅλα σὲ ἕνα» σύστημα γνώσης ποὺ εἶχα φανταστεῖ. Αὐτὴ ἡ ἔκδοση ἐπιτρέπει προβολὴ συνδεδεμένων κόμβων τοῦ org-gnosis καὶ τῶν συνδεδεμένων themata τους σὲ tabulated-list μέσω τοῦ gnosis-dashboard μὲ ἐξαιρετικὴ ἐπίδοση.

Δὲν χρειάζονται πιὰ ἐξωτερικοὶ περιηγητὲς γιὰ νὰ βλέπω τὴ συλλογή μου. Αὐτὸ σημαίνει ὅτι τὸ ἔργο org-gnosis-ui θὰ πρέπει νὰ θεωρεῖται παρωχημένο. Ὅλες οἱ λειτουργίες μποροῦν τώρα νὰ γίνουν ἐντὸς Ἤμαξ.

Ἐπιπλέον, ἔχω δημοσιεύσει ἕνα gnosis-deck εἰδικὰ σχεδιασμένο γιὰ συναδέλφους φοιτητὲς ἰατρικῆς, ὀνομαζόμενο Unking, βασισμένο στὴν τελευταία δωρεὰν ἔκδοση τοῦ Anking deck, Anking V11. Αὐτὸ τὸ deck εἶναι ἀρκετὰ περιεκτικό, μὲ πάνω ἀπὸ 40.000 themata.

Καθὼς τὸ Gnosis ἤδη ἐκπληρώνει τὶς ἀρχικές μου προθέσεις καὶ πέρα, ἡ περαιτέρω ἀνάπτυξη θὰ ἐστιαστεῖ κυρίως σὲ διορθώσεις σφαλμάτων καὶ γενικὴ συντήρηση παρὰ σὲ νέα μεγάλα χαρακτηριστικά. Ἡ προτεραιότητά μου τώρα θὰ μετατοπιστεῖ πρὸς τὴ χρήση τοῦ συστήματος γιὰ τὶς ἐξετάσεις μου παρὰ πρὸς τὴ συνέχιση ἐνεργῆς ἀνάπτυξης.

Ὑπῆρξε πραγματικὰ εὐχάριστο καὶ ἀνταποδοτικὸ νὰ δουλεύω σὲ αὐτὸ τὸ ἔργο. Ὁ στόχος μου γιὰ νὰ μάθω προγραμματισμὸ ἦταν νὰ φτιάξω ἕνα σύστημα γνώσης καὶ νὰ μὴν βασίζομαι σὲ τρίτους γιὰ τὴ μελέτη μου.

Τὸ ὁποῖο ἐπιτέλους πέτυχα:) Αὐτὸ δὲν θὰ ἦταν δυνατὸ χωρὶς ὅλη τὴ δουλειὰ ποὺ πολλοὶ ἀπὸ ἐσᾶς ἔχετε βάλει στὸ οἰκοσύστημα Ἤμαξ, ὁπότε ἁπλῶς θέλω νὰ ἐκφράσω τὴν εἰλικρινῆ μου εὐγνωμοσύνη σὲ ὅλους σας, εὐχαριστῶ!

Νέα χαρακτηριστικὰ

• Αὐτόματη ἀνίχνευση μεθόδου εἰσαγωγῆς: τὸ gnosis ἀνιχνεύει τὴ γραφὴ τῆς ἀναμενόμενης ἀπάντησης (ἑλληνικά, κυριλλικά, κ.λπ.) καὶ ἐνεργοποιεῖ τὴν κατάλληλη μέθοδο εἰσαγωγῆς κατὰ τὴν ἐπανάληψη. Ρυθμίζεται μέσω gnosis-script-input-method-alist.
• Ἀλλαγὴ τύπου thema καὶ deck μέσω gnosis-update-thema.
• Ἐνέργεια μαζικῆς σύνδεσης τοῦ πίνακα γιὰ τὰ τρέχοντα ἐμφανιζόμενα themata.
• Γραμμὴ κεφαλίδας πίνακα μὲ ἀριθμὸ καταχωρίσεων καὶ πλαίσιο.
• Ἀσύγχρονη εἰσαγωγὴ deck μὲ gnosis-import-deck-async.
• Δεῖγμα deck συμπεριλαμβάνεται στὸ decks/demo.org.

Ἐπίδοση

• Νέα μονάδα gnosis-tl ἀντικαθιστᾶ τὸ tabulated-list-print γιὰ ἀπόδοση πίνακα (3-4x ταχύτερη).
• Προοδευτικὴ ἀσύγχρονη ἀπόδοση γιὰ μεγάλους πίνακες.
• Μαζικὴ ἀνάκτηση δεδομένων ἐπανάληψης ἀντὶ ἐρωτημάτων ἀνὰ thema.

Διορθώσεις σφαλμάτων

• Διόρθωση ὑπολογισμοῦ γεγονότος anagnosis στὸν ἀλγόριθμο.
• Διόρθωση ἀφαίρεσης ἐτικέτας cloze γιὰ ἀκραῖες περιπτώσεις καὶ τύπο mc-cloze.
• Διόρθωση vc-pull νὰ τρέχει μεταπτώσεις βάσης δεδομένων μετὰ τὴ λήψη.

Τὸ Notmuch ὑπῆρξε ἐξαιρετικὰ χρήσιμο γιὰ μένα τὸν περασμένο χρόνο, καὶ ἐλπίζω αὐτὸς ὁ ὁδηγὸς νὰ βοηθήσει νέους χρήστες νὰ ξεπεράσουν τὰ ἀρχικὰ ἐμπόδια.

Σημειώσεις βίντεο:

Σύνοψις

• Ἐπίδειξη ροῆς ἐργασίας ἠλεκτρονικοῦ ταχυδρομείου Ἤμαξ μὲ notmuch.el.
  • Ἀποστολὴ μηνυμάτων ἀπὸ πολλαπλὲς διευθύνσεις, χρησιμοποιώντας smtpmail.
  • Αὐτόματη κρυπτογράφηση μηνυμάτων ἠλεκτρονικοῦ ταχυδρομείου, ἂν ὑπάρχει διαθέσιμο κλειδὶ pgp, χρησιμοποιώντας mml-sec.

Γιατί notmuch

• Ἐνσωματωμένη ὑποστήριξη Ἤμαξ, μὲ notmuch.el.
  • Πακέτα ὅπως ol-notmuch φέρνουν ἐνσωμάτωση μὲ τὸ ὑπόλοιπο οἰκοσύστημα Ἤμαξ.
• Τὸ Notmuch εἶναι σύστημα βασισμένο σὲ ἐτικέτες. Δὲν βασίζεσαι στὸν πάροχο ἠλεκτρονικοῦ ταχυδρομείου σου γιὰ κανόνες φίλτρων κ.λπ. γιὰ νὰ ὀργανώσεις τὴν ἀλληλογραφία σου σὲ ξεχωριστὰ γραμματοκιβώτια.
  • Πράγμα ποὺ εἶναι ἀναποτελεσματικὸ ἐξαρχῆς ὅταν δουλεύεις μὲ χιλιάδες++ μηνύματα ἠλεκτρονικοῦ ταχυδρομείου.
  • Αὐτὸ ἐπίσης κάνει εὐκολότερη τὴ μετάβαση σὲ νέο πάροχο ἠλεκτρονικοῦ ταχυδρομείου.
• Τοπικὴ ἀποθήκευση ἀλληλογραφίας.
• Ἐξαιρετικὴ ἐπίδοση γιὰ φιλτράρισμα καὶ ἀναζήτηση μέσα ἀπὸ ἑκατοντάδες χιλιάδες μηνύματα.

Ὑποθέσεις ποὺ κάνω γιὰ αὐτὸ τὸ βίντεο

Ἔχεις λειτουργικὴ διαμόρφωση Ἤμαξ

Ὁ πάροχος ἠλεκτρονικοῦ ταχυδρομείου σου ὑποστηρίζει ἀνάκτηση καὶ ἀποστολὴ ἀλληλογραφίας μέσω ἐφαρμογῶν τρίτων

• Ἤδη ξέρεις πῶς νὰ ρυθμίσεις isync/mbsync γιὰ ἀνάκτηση μηνυμάτων ἠλεκτρονικοῦ ταχυδρομείου ἀπὸ ἀπομακρυσμένο διακομιστή.
• Ὁ πάροχος ἠλεκτρονικοῦ ταχυδρομείου σου προσφέρει διαπιστευτήρια smtp γιὰ χρήση ἐφαρμογῶν τρίτων.
  • Προσωπικὰ συνιστῶ νὰ δοκιμάσεις τὸ purelymail.com κοστίζει μόνο 10$/χρόνο καὶ προσφέρει καλὴ ὑπηρεσία.

Παράδειγμα διαμόρφωσης isyncrc ~/.config/isyncrc

IMAPAccount gmail
Host imap.gmail.com
Port 993
User user@gmail.com # Change this to your username.
PassCmd "pass gmail/account" # Change this to a command that returns your password.
TLSType IMAPS
TLSVersions +1.2
CertificateFile /etc/ssl/certs/ca-certificates.crt

IMAPStore gmail-remote
Account gmail

MaildirStore gmail-local
Path ~/Mail/gmail/
Inbox ~/Mail/gmail/Inbox
Trash ~/Mail/gmail/Trash
SubFolders Verbatim

Channel gmail
Far :gmail-remote:
Near :gmail-local:
Patterns *
Expunge None
CopyArrivalDate yes
Sync All
Create Both
SyncState *

Μετὰ τὴν προσαρμογὴ τῆς παραπάνω διαμόρφωσης, τρέξε mbsync -a γιὰ νὰ συγχρονίσεις τὸ ἀπομακρυσμένο γραμματοκιβώτιο τοπικά.

Ρύθμιση notmuch

Πρώτη ἐγκατάσταση

• Μετὰ τὴν ἐγκατάσταση notmuch γιὰ πρώτη φορά, τρέξε notmuch setup γιὰ διαδραστικὴ ρύθμιση.

Δημιούργησε ~/.scripts/notmuch-hook.sh

• Σενάριο Bash ποὺ θὰ φιλτράρει/ἐπισημαίνει τὴν ἀλληλογραφία σου

Παράδειγμα:

#!/bin/sh
notmuch new
# Add +inbox tag to a specific alias/address
notmuch tag +inbox -- to:main@address.org

#Sent messages, change this to your mail addresses
notmuch tag -unread -new -inbox +sent -- from:*@mydomain.org or from:*@mydomain.com or from:user@gmail.com

# Example for Emacs-devel
notmuch tag +emacs-devel -new -inbox -- from:emacs-devel@gnu.org or to:emacs-devel@gnu.org

# Example for Github
notmuch tag +github -- from:*github.com

# Filter based on other tags, such as drafts
notmuch tag -inbox -sent -inbox -- tag:draft

Διαμόρφωση Ἤμαξ

Notmuch

(use-package notmuch
  :config
  (defun thanos/notmuch-update--command (new-buffer)
    (let ((default-directory "~/.scripts/")) ;; Directory where notmuch script is located.
      (async-shell-command "mbsync -a; ./notmuch-hook.sh" new-buffer)))

  (defun thanos/notmuch-update ()
    (interactive)
    (let* ((buffer (generate-new-buffer "*notmuch update*"))
           (height (max 5 (truncate (* (frame-height) 0.1))))
           (window (split-window-vertically (- height))))
      (with-selected-window window
        (switch-to-buffer buffer)
        (let ((proc (thanos/notmuch-update--command buffer)))
          (set-process-sentinel
           (get-buffer-process buffer)
           (lambda (process event)
             (when (memq (process-status process) '(exit signal))
               (delete-window (get-buffer-window (process-buffer process)))
               (kill-buffer (process-buffer process)))))))))

  (defun thanos/notmuch-search ()
    "Custom notmuch-search wrapper, that makes sure we have newest mail first."
    (interactive)
    (let ((query (notmuch-read-query "Notmuch search: ")))
      (notmuch-search query nil)))

  ;; Configure saved searches to your liking, here's an example:
  (setf notmuch-saved-searches
        `((:name "Week's Inbox" :query "tag:inbox date:7d..today" :sort-order newest-first
                 :key ,(kbd "i"))
          (:name "Inbox" :query "tag:inbox" :sort-order newest-first :key ,(kbd "I"))
          (:name "Unread" :query "tag:unread" :sort-order newest-first :key ,(kbd "u"))
          (:name "Today's message" :query "tag:inbox date:today"
                 :sort-order newest-first :key ,(kbd "t"))
          (:name "sent" :query "tag:sent" :sort-order newest-first :key ,(kbd "s"))
          (:name "drafts" :query "tag:draft" :sort-order newest-first :key ,(kbd "d"))
          (:name "all mail" :query "*" :sort-order oldest-first :key ,(kbd "a"))))
  ;; Tag format configuration
  (setf notmuch-tag-formats
        '(("unread" (propertize tag 'face 'notmuch-tag-unread))))
  :bind (("C-x m" . notmuch-hello)
         :map notmuch-hello-mode-map
         ("u" . notmuch-hello-update)
         ("U" . thanos/notmuch-update)
         ("s" . thanos/notmuch-search)
         :map notmuch-search-mode-map
         ("u" . notmuch-refresh-all-buffers)))

smtpmail

• Αὐτὴ ἡ διαμόρφωση χρησιμοποιεῖται γιὰ ἀποστολὴ μηνυμάτων ἠλεκτρονικοῦ ταχυδρομείου ἀπὸ πολλαπλὲς διευθύνσεις· βεβαιώσου ὅτι ἔχεις ἀποθηκευμένο τὸν κωδικὸ πρόσβασης στὸ ~/.authinfo.gpg ποὺ ὁ Ἤμαξ θὰ χρησιμοποιήσει ἐκ προεπιλογῆς.

(use-package smtpmail
  :config
  ;; Default credentials
  (setf smtpmail-smtp-user (auth-source-pass-get "user" "gmail/user") ;; This is not your password, just the username.  Emacs will search for your pw in ~/.authinfo.gpg.
        smtpmail-smtp-server "smtp.gmail.com"
        smtpmail-smtp-service 465 ;; Adjust this to your mail provider port if needed
        smtpmail-stream-type 'ssl
        message-send-mail-function 'smtpmail-send-it
        message-signature "My signature")

  (defun thanos/mail-config-hook ()
    (let ((from (mail-fetch-field "From"))
          (public "<public@thanosapollo.org>")
          (gmail "<104111@students.mu-sofia.bg>"))
      (cond ((string-match public from)
             (setf smtpmail-smtp-user (auth-source-pass-get "user" "purelymail/thanosapollo")
                   smtpmail-smtp-server "smtp.purelymail.com"))
            ((string-match gmail from)
             (setf smtpmail-smtp-user "104111@students.mu-sofia.bg"
                   smtpmail-smtp-server "smtp.gmail.com")))))
  ;; You can use :hook instead, but I prefer add-hook under :config personally.
  (add-hook 'message-send-hook #'thanos/mail-config-hook))

mml-sec

(use-package mml-sec
  :config
  (defun gpg-list-emails-available ()
  "Return a list of trusted emails.
Parses output of `gpg --list-keys --with-colons' command into a
list of emails."
  (let* ((command "gpg --list-keys --with-colons")
         (output (shell-command-to-string command))
         (lines (split-string output "\n" t))
         (emails '()))
    (dolist (line lines)
      (when (string-prefix-p "uid:" line)
        (when (string-match "<\\([^>]+\\)>" line)
          (let ((email (downcase (string-trim (match-string 1 line)))))
            (push email emails)))))
    (delete-dups emails)))

  (defun thanos/mail-list-recipients-from-buffer ()
    "Get the list of recipients from the current email buffer."
    (save-excursion
      (goto-char (point-min))
      (let ((to (or (mail-fetch-field "To") ""))
            (cc (or (mail-fetch-field "Cc") ""))
            (bcc (or (mail-fetch-field "Bcc") ""))
            recipients)
        (setq recipients (concat to ", " cc ", " bcc))
        ;; Remove empty strings from the result
        (delq nil
              (mapcar (lambda (addr)
                        (let ((clean-addr (string-trim addr)))
                          (when (not (string-empty-p clean-addr))
                            (downcase
                             (if (string-match "<\\([^>]+\\)>" clean-addr)
                                 (string-trim (match-string 1 clean-addr))
                               clean-addr)))))
                      (split-string recipients "," t))))))

  (defun thanos/mail-sign-encrypt ()
    "Auto-encrypt if all recipients have keys, else just sign."
    (let ((trusted-emails (gpg-list-emails-available))
          (recipients (thanos/mail-list-recipients-from-buffer)))
      (if (cl-every (lambda (r) (member r trusted-emails)) recipients)
          (progn
            (message "Encrypting message.")
            (mml-secure-message-sign-encrypt))
        (progn
          (message "Just signing message.")
          (mml-secure-message-sign)))))

  (add-hook 'message-send-hook #'thanos/mail-sign-encrypt)
  :custom
  (mml-secure-openpgp-signers '("62B758D0F6719938BC09CECA339F736C3A720928"))) ;; Change this to your own key!

Ὑποστήριξη Org Mode

Μετὰ ἀπὸ δουλειὰ/πειραματισμὸ στὸ org-gnosis καὶ καλύτερη κατανόηση τοῦ πῶς δουλεύει τὸ org-mode, ἀποφάσισα νὰ χρησιμοποιήσω org-mode γιὰ δημιουργία καὶ ἐξαγωγὴ σημειώσεων gnosis.

Οἱ σημειώσεις, ἀνεξαρτήτως τύπου, θὰ εἶναι πλέον ὡς ἑξῆς:

Παράδειγμα τύπου cloze.

* Thema                      :pharmacology:antimicrobials:penicillin:
:PROPERTIES:
:GNOSIS_ID: NEW
:GNOSIS_TYPE: cloze
:END:
** Keimenon
What is the treatment for Actinomyces infection?

Penicillin

** Hypothesis
- drug type

** Answer
- Penicillin

** Parathema
Sulfonamides → Nocardia
Actinomyces → [[id:680ca944-8ee9-4513-92d6-25696ee01f48][Penicillin]]
(treatment is a SNAP)

Σημείωσε ὅτι ἡ σύνταξη τύπου anki ἐξακολουθεῖ νὰ ὑποστηρίζεται γιὰ clozes.

Παράδειγμα MCQ

* Thema                                                            :clinical:
:PROPERTIES:
:GNOSIS_ID: NEW
:GNOSIS_TYPE: mcq
:END:
** Keimenon
A 60-year-old man comes to the physician with chills, nausea, and
diffuse muscle aches for 3 days. His niece had similar symptoms 2
weeks ago and H3N2 influenza strain was isolated from her respiratory
secretions. He received his influenza vaccination 2 months ago. His
temperature is 38.5°C. A rapid influenza test is
positive. Which of the following mechanisms best explains this
patient's infection despite vaccination?

** Hypothesis
- Random point mutations within viral genome
- Complementing with functional viral proteins
- Exchange of viral genes between chromosomes
- Reassortment of viral RNA segments
- Acquisition of viral surface proteins

** Answer
- Random point mutations within viral genome

** Parathema
Random point mutations within the viral genome are responsible for
antigenic drift, which creates a new virus strain.

Κάθε σημείωση εἶναι ἕνα thema ποὺ ἀποτελεῖται ἀπὸ τὰ ἑξῆς στοιχεῖα:

• *Keimenon*· Τὸ κύριο κείμενο ἢ ἡ ἐρώτηση.
• *Hypothesis*· Ὑποθέσεις/ὑποδείξεις γιὰ τὸ κείμενο ποὺ ὁδηγοῦν στὴ σωστὴ ἀπάντηση
  • Γιὰ παράδειγμα χρησιμοποιεῖται ὡς ὑποδείξεις γιὰ τύπο cloze ἢ ὡς ἐπιλογὲς σὲ MCQ
• *Answer*· Ἡ σωστὴ ἀπάντηση ἢ λύση στὸ keimenon.
• *Parathema*· ἐπέκταση τοῦ keimenon, ποὺ μπορεῖ νὰ περιλαμβάνει συνδέσμους π.χ. σὲ θέματα org-gnosis ἢ ἀκόμα καὶ ἀρχεῖα, ὡς τρόπος σύνδεσης θεμάτων org-gnosis μὲ τὸ τρέχον thema.

Προαιρετικά, μπορεῖς ἐπίσης νὰ προσθέσεις ἐτικέτες σὲ κάθε σημείωση.

Οἱ σημειώσεις/themata μποροῦν νὰ ἔχουν πολλαπλὲς hypotheses καὶ ἀπαντήσεις (ἀνάλογα μὲ τὸν τύπο τους), διαχωρισμένες μὲ gnosis-export-separator, ποὺ ἐξ ὁρισμοῦ εἶναι "\n-" (νέα γραμμὴ ἀκολουθούμενη ἀπὸ παύλα).

Ὑποστήριξη ἐξαγωγῆς decks

Προστέθηκε ὑποστήριξη ἐξαγωγῆς decks ὡς ἀρχεῖα org μέσω gnosis-export-deck.

Ὑποστήριξη σημειώσεων org-gnosis

Μὲ αὐτὴ τὴν ἐνημέρωση τὸ org-gnosis εἶναι ἐπιτέλους μέρος τοῦ gnosis. Ὁ στόχος δὲν εἶναι ἁπλῶς ἕνα ἐργαλεῖο ἐπανάληψης μὲ διαστήματα, ἀλλὰ ἕνα ὁλοκληρωμένο ἐργαλεῖο μάθησης.

Μὲ αὐτὴ τὴ νέα ἐνημέρωση μπορεῖς νὰ κάνεις ἐπαναλήψεις γιὰ συγκεκριμένα θέματα org-gnosis.

• Χρησιμοποίησε M-x gnosis-review-topic γιὰ νὰ ἐπιλέξεις θέμα ἀπὸ τὶς σημειώσεις org-gnosis καὶ νὰ ἐπαναλάβεις ὅλα τὰ συνδεδεμένα themata.
• Μπορεῖς νὰ συνδέσεις ἕνα thema μὲ θέμα org-gnosis προσθέτοντας σύνδεσμο org id εἴτε στὸ parathema (συνιστᾶται) εἴτε στὸ keimenon, μὲ M-x org-gnosis-insert.

Μελλοντικὲς ἐκδόσεις θὰ ἐπεκτείνουν περαιτέρω αὐτὴ τὴ λειτουργικότητα.

Παρωχημένη ὑποστήριξη εἰκόνων

• Ἡ ὑποστήριξη εἰκόνων θὰ ξαναγραφεῖ στὴν ἑπόμενη δευτερεύουσα ἔκδοση
  • Θὰ προστεθεῖ ὑποστήριξη ἐμφάνισης συνδέσμων ἀρχείων εἰκόνων.

Παρωχημένη ὑποστήριξη σημειώσεων y-or-n

Μὲ αὐτὴ τὴν ἐνημέρωση οἱ τρέχουσες σημειώσεις y-or-n θὰ μετατραποῦν σὲ τύπο MCQ, μὲ ἐπιλογὲς «Ναί» καὶ «Ὄχι».

Θὰ ἔλεγα ἡ σωστὴ ὀργάνωση αὐτῆς τῆς γνώσης, ὅπως μὲ decks γιὰ κάθε ἀντικείμενο καὶ οὐσιώδεις ἐτικέτες ποὺ συνδέουν σχετικὲς ἔννοιες μεταξύ decks, κάνοντάς την εὔκολα ἀναζητήσιμη καὶ προσβάσιμη.

Καθὼς ἄρχισα νὰ προσθέτω ὅλο καὶ περισσότερες σημειώσεις στὴ gnosis, βρέθηκα νὰ θέλω νὰ προσαρμόζω τὸν ἀλγόριθμο ἐπανάληψης ὄχι μόνο γιὰ decks ἀλλὰ καὶ γιὰ ἐτικέτες. Αὐτὸ μὲ ὁδήγησε νὰ ἀναδιαμορφώσω τὴν ὑποκείμενη ἀρχιτεκτονικὴ καὶ νὰ ξαναϋλοποιήσω βασικὲς ἔννοιες.

Κύριες ἀλλαγές

• Ἀνασχεδιασμὸς τοῦ gnosis-dashboard μὲ buffer σὰν ἀρχικὴ σελίδα ποὺ ἐμφανίζει τρέχοντα στατιστικὰ δραστηριότητας, ὅπως σειρὰ ἐπανάληψης καὶ τὶς σημειώσεις ποὺ εἶναι προγραμματισμένες γιὰ σήμερα.
• Ξαναγραμμένος ἀλγόριθμος gnosis:
  • Προστέθηκε gnosis-score, ἡ τρέχουσα βαθμολογία γνώσης γιὰ μία σημείωση.
  • Προστέθηκε τιμὴ epignosis, ποὺ δείχνει τὴν ἀκρίβεια γνώσης γιὰ δεδομένη σημείωση, καθὼς καὶ agnoia γιὰ τὴν ἔλλειψη γνώσης μιᾶς σημείωσης· αὐτὲς οἱ τιμὲς θὰ χρησιμοποιηθοῦν σὲ γεγονότα anagnosis. Τὰ ὀνόματα εἶναι ἑλληνικὲς λέξεις· epignosis ≈ ἐπίγνωσις, agnoia ≈ ἄγνοια.
  • Προστέθηκαν εἰδικὰ γεγονότα ἐπανάληψης· Anagnosis & Lethe
    • Anagnosis ἀναφέρεται στὴν ἀναγνώριση καὶ κατανόηση ἑνὸς πλαισίου· τὰ γεγονότα anagnosis πυροδοτοῦνται εἴτε ἀπὸ διαδοχικὲς ἀποτυχημένες εἴτε ἀπὸ ἐπιτυχεῖς ἀνακλήσεις. Ἀνάλογα μὲ τὸ πῶς πυροδοτοῦνται, ἐφαρμόζεται epignosis ἢ agnoia στὸ gnosis-score
    • Lethe ἀναφέρεται στὴ λήθη τῆς γνώσης· πυροδοτεῖται ἀπὸ διαδοχικὲς ἀποτυχίες ἀνάκλησης ἀπάντησης· μὲ αὐτὸ τὸ γεγονὸς τὸ ἑπόμενο διάστημα ὁρίζεται σὲ 0
  • Προστέθηκε *amnesia*· ὅταν ἀποτυγχάνεις νὰ ἀνακαλέσεις μία σημείωση, ἡ τιμὴ amnesia χρησιμοποιεῖται γιὰ νὰ καθορίσει τὸ ἑπόμενο διάστημα.
  • Προστέθηκε proto, μία λίστα ἀκεραίων ποὺ δείχνει τὶς τιμὲς γιὰ τὰ πρῶτα διαστήματα. Ἡ λίστα proto δὲν ἔχει ὅριο μῆκους.
• Ξαναϋλοποιήθηκε ἡ διαμόρφωση γιὰ τὶς παραπάνω τιμὲς deck καὶ προστέθηκε ἡ ἱκανότητα νὰ κάνεις τὸ ἴδιο γιὰ ἐτικέτες. Ἡ διαμόρφωση ἐτικέτας ἔχει προτεραιότητα πάνω ἀπὸ τὴ διαμόρφωση deck.

Παράδειγμα:

(setq gnosis-custom-values
  '((:deck "demo" (:proto (0 1 3) :anagnosis 3 :epignosis 0.5 :agnoia 0.3 :amnesia 0.5 :lethe 3))
    (:tag "demo-concept" (:proto (1 2) :anagnosis 3 :amnesia 0.7))))

Μία σημείωση κάτω ἀπὸ τὸ deck demo μὲ ἐτικέτα demo-concept θὰ ἔχει τὶς τιμὲς τοῦ deck demo μὲ ἐξαίρεση:

• τιμὴ proto ὁρισμένη σὲ (1 2)
• τιμὴ amnesia ὁρισμένη σὲ 0.7

Γιὰ σημειώσεις μὲ πολλαπλὲς ἐτικέτες, διατηρεῖται ἡ μέγιστη τιμὴ γιὰ τὶς περισσότερες παραμέτρους. Ὡστόσο, τὰ anagnosis καὶ lethe διατηροῦν τὴν ἐλάχιστη τιμὴ.

Ἑπόμενα χαρακτηριστικὰ στὸν ὁρίζοντα

• Ἐνσωμάτωση Org mode
• Ἐξαγωγὴ καὶ εἰσαγωγὴ deck

Σχετικά

Σὲ αὐτὸν τὸν ὁδηγὸ θὰ σὲ καθοδηγήσω στὴν ἐγκατάσταση mu4e μὲ πολλαπλοὺς λογαριασμούς, χρησιμοποιώντας isync καὶ mu, καθὼς καὶ στὰ βασικὰ τοῦ πῶς νὰ ἐνσωματώσεις τὸ mu4e στὴ ροὴ ἐργασίας σου, συν συμβουλὲς καὶ κόλπα ὅπως χρήση ἐνεργειῶν τοῦ mu4e γιὰ ἐφαρμογὴ διορθώσεων Git.

Γιὰ νὰ ἀκολουθήσεις αὐτὸν τὸν ὁδηγό, βεβαιώσου ὅτι ἔχεις ἐνεργοποιήσει πρόσβαση IMAP/SMTP γιὰ τὸν λογαριασμὸ ἠλεκτρονικοῦ ταχυδρομείου σου. Τὰ βήματα ἐνεργοποίησης μπορεῖ νὰ διαφέρουν ἀνάλογα μὲ τὸν συγκεκριμένο πάροχο ἠλεκτρονικοῦ ταχυδρομείου, ὁπότε δὲν θὰ τὰ καλύψω ἐδῶ.

Γιατί mu4e;

Ὑπάρχουν πολλαπλὲς ἐπιλογὲς στὸν GNU Ἤμαξ γιὰ διαχείριση ἠλεκτρονικοῦ ταχυδρομείου, ὅπως rmail, gnus, notmuch καὶ mu4e.

Καθεμία ἀπὸ αὐτὲς τὶς ἐπιλογὲς ἔχει τὶς δικές της πολυπλοκότητες, ἀνάλογα μὲ τὴ συγκεκριμένη περίπτωση χρήσης σου.

Στὴν προσωπική μου ἐμπειρία, προτιμῶ τὸ mu4e λόγω τῆς εὐκολίας ἐγκατάστασης, ἰδίως ὅταν ἔχεις νὰ κάνεις μὲ πολλαπλοὺς λογαριασμούς.

Ἐγκατάσταση MU & isync

Γιὰ νὰ ξεκινήσεις, ἐγκατάστησε mu καὶ isync

• Arch Linux

$ sudo pacman -S mu isync

• Gentoo

$ sudo emerge -av mu isync

NOTE: Βεβαιώσου ὅτι χρησιμοποιεῖς emacs USEFLAG γιὰ τὸ mu

Ἂν τὸ mu δὲν εἶναι πακεταρισμένο γιὰ τὴ διανομή σου, συστήνω νὰ ἀλλάξεις σὲ νέα. Ἀλλὰ ἂν ἐπιμένεις, ἴσως ἔχεις ἐπιτυχία ἐγκαθιστώντας mu ἀπὸ πηγή, χρησιμοποιώντας straight.el:

(straight-use-package 'mu4e)

Ρύθμιση mbsync

Ἐπεξεργάσου τὴ διαμόρφωσή σου: ~/.mbsyncrc

Παράδειγμα ρύθμισης γιὰ Fastmail:

IMAPAccount fastmail
Host imap.fastmail.com
Port 993
User myaccount@fastmail.com
PassCmd "emacsclient -e '(password-store-get-field \"fastmail.com/myaccount@fastmail.com\" \"smtp\)'"
SSLType IMAPS
SSLVersions TLSv1.2
CertificateFile /etc/ssl/certs/ca-certificates.crt

IMAPStore fastmail-remote
Account fastmail

MaildirStore fastmail-local
Path ~/Mail/Fastmail/
Inbox ~/Mail/Fastmail/Inbox
Trash ~/Mail/Fastmail/Trash/
SubFolders Verbatim

Channel fastmail
Far :fastmail-remote:
Near :fastmail-local:
Patterns *
Expunge None
CopyArrivalDate yes
Sync All
Create Both
SyncState *

Παράδειγμα ρύθμισης γιὰ Gmail:

IMAPAccount gmail
Host imap.gmail.com
Port 993
User myaccount@gmail.com
PassCmd "pass google/mygmail.com"
SSLType IMAPS
SSLVersions TLSv1.2
CertificateFile /etc/ssl/certs/ca-certificates.crt

IMAPStore gmail-remote
Account gmail

MaildirStore gmail-local
Path ~/Mail/Account-GMAIL/
SubFolders Verbatim

Channel gmail
Far :gmail-remote:
Near :gmail-local:
Patterns * ![Gmail]* "[Gmail]/Sent Mail" "[Gmail]/Starred" "[Gmail]/All Mail" "[Gmail]/Trash"
Expunge None
CopyArrivalDate yes
Sync All
Create Both
SyncState *
Settings you should adjust:

• PassCmd αὐτὸ θὰ πρέπει νὰ ἐξάγει τὸν κωδικὸ τοῦ λογαριασμοῦ σου. Προσωπικὰ χρησιμοποιῶ pass ὡς διαχειριστὴ κωδικῶν.

Στὸ παραπάνω παράδειγμα fastmail παίρνω τὸν κωδικὸ μὲ αὐτὴ τὴ συνάρτηση Ἤμαξ:

(password-store-get-field \"fastmail.com/myaccount@fastmail.com\" \"smtp\)

Τὸ password-store εἶναι διεπαφὴ τοῦ pass γιὰ τὸν Ἤμαξ.

NOTE: Ἀντὶ γιὰ PassCmd, μπορεῖς νὰ χρησιμοποιήσεις Pass ποὺ ἁπλῶς ἔχει τὸν κωδικό σου σὲ ἀπλὸ κείμενο, ἀλλὰ δὲν τὸ συστήνω γιὰ λόγους ἀσφαλείας.

• CertificateFile - Αὐτὴ ἡ τοποθεσία μπορεῖ νὰ διαφέρει ἀνάλογα μὲ τὴ διανομὴ Linux σου.

• Patterns - Ὁρίζει ποιοὶ φάκελοι θὰ συγχρονιστοῦν· προσωπικὰ ἁπλῶς ὁρίζω τοὺς φακέλους μου χειροκίνητα, παρόμοια μὲ τὸ παράδειγμα fastmail.

Μὴ διστάσεις νὰ ὁρίσεις πολλαπλοὺς λογαριασμοὺς μὲ αὐτὸν τὸν τρόπο.

Μετὰ τὴ διαμόρφωση τοῦ isync, ξεκίνα τὸν ἀρχικὸ συγχρονισμὸ τρέχοντας αὐτὴ τὴν ἐντολή:

$ mbsync -a

Ρύθμιση mu & mu4e

Πρῶτα, πρέπει νὰ τρέξεις τὴν ἀρχικὴ εὐρετηρίαση.

mu init --maildir=~/Mail --my-address myaccount@fastmail.com
mu index

NOTE: Μπορεῖς νὰ προσθέσεις ὅσα ὁρίσματα --my-address θέλεις.

Τώρα εἶναι ὥρα νὰ δημιουργήσεις τὴ διαμόρφωση mu4e γιὰ Ἤμαξ.

Μπορεῖς νὰ τὴ δημιουργήσεις ὡς μονάδα, ἢ ἁπλῶς ὡς μέρος τοῦ :config μὲ use-package. Προσωπικὰ ὁρίζω μεταβλητὲς στὸ init.el μου ἔτσι:

(defvar is-desktop (equal (system-name) "desktop-hostname")) ;; your $HOSTNAME
(defvar is-laptop (equal (system-name) "laptop-hostname"))

Δημιούργησε ~/.emacs.d/modules/thanos-mu4e.el γιὰ τὴ διαμόρφωση μονάδας mu4e. Καὶ πρόσθεσε αὐτὸ στὸ init.el μου

(add-to-list 'load-path "~/.emacs.d/modules")

(when (or is-desktop is-laptop)
  (require 'thanos-mu4e))

Ἔτσι φορτώνω τὴ διαμόρφωση mu4e μόνο ὅταν χρησιμοποιῶ φορητὸ ἢ ἐπιτραπέζιο ὑπολογιστή.

Φόρτωση Mu4e

Βεβαιώσου ὅτι τὸ mu4e εἶναι στὸ load-path:

(add-to-list 'load-path "/usr/share/emacs/site-lisp/mu4e/") ;; path to mu4e
(require 'mu4e)

Τὰ οὐσιώδη

Αὐτὸ εἶναι ἕνα παράδειγμα διαμόρφωσης γιὰ νὰ ξεκινήσεις μὲ mu4e χρησιμοποιώντας πολλαπλοὺς λογαριασμούς:

(setf mu4e-get-mail-command "mbsync -a")

(when (and is-desktop (server-running-p))
  (setf mu4e-update-interval (* 10 60)))

;; Snippet from EmacsWiki
(defun set-mu4e-context (context-name full-name mail-address signature)
  "Return a mu4e context named CONTEXT-NAME with :match-func matching
    folder name CONTEXT-NAME in Maildir. The context's `user-mail-address',
    `user-full-name' and `mu4e-compose-signature'`smtpmail-smpt-server' is set to MAIL-ADDRESS
    FULL-NAME SIGNATURE and SERVER respectively.
    Special folders are set to context specific folders."
  (let ((dir-name (concat "/" context-name)))
    (make-mu4e-context
     :name context-name
     ;; we match based on the maildir of the message
     :match-func
     `(lambda (msg)
    (when msg
      (string-match-p
       ,(concat "^" dir-name)
       (mu4e-message-field msg :maildir))))
     :vars
     `((user-mail-address    . ,mail-address)
       (user-full-name       . ,full-name)
       (mu4e-sent-folder     . ,(concat dir-name "/Sent"))
       (mu4e-drafts-folder   . ,(concat dir-name "/Drafts"))
       (mu4e-trash-folder    . ,(concat dir-name "/Trash"))
       (mu4e-trash-folder    . ,(concat dir-name "/Starred"))
       (mu4e-refile-folder   . ,(concat dir-name "/Archive"))
       (mu4e-compose-signature . ,signature)))))

;;Fixing duplicate UID errors when using mbsync and mu4e
(setf mu4e-change-filenames-when-moving t)

(setf mu4e-maildir-shortcuts
      '(("/Fastmail/Inbox" . ?f)
    ("/Drafts" . ?d)
    ("/Sent" . ?s)
    ("/Gmail-Account/[Gmail]/All Mail" . ?g)

(setf mu4e-contexts
      (list
       (make-mu4e-context
    :name "fastmail"
    :match-func
    (lambda (msg)
      (when msg
        (string-prefix-p "/Fastmail" (mu4e-message-field msg :maildir))))
    :vars '((user-mail-address . "username@fastmail.com")
        (user-full-name    . "User Name")
        (smtpmail-smtp-server . "smtp.fastmail.com")
        (smtpmail-smtp-service . 465)
        (smtpmail-stream-type . ssl)
        (mu4e-drafts-folder  . "/Drafts")
        (mu4e-sent-folder  . "/Sent")
        (mu4e-refile-folder  . "/Archive")
        (mu4e-trash-folder  . "/Trash")))
        ;; You can comment out the second account.
       (make-mu4e-context
    :name "gmail"
    :match-func
    (lambda (msg)
      (when msg
        (string-prefix-p "/Gmail-Account" (mu4e-message-field msg :maildir))))
    :vars '((user-mail-address . "username@gmail.com")
        (user-full-name    . "User Name")
        (smtpmail-smtp-server . "smtp.gmail.com")
        (smtpmail-smtp-service . 465)
        (smtpmail-stream-type . ssl)))))

(setf message-send-mail-function 'smtpmail-send-it
      mu4e-compose-signature "My Signature"
      mu4e-compose-context-policy 'ask)

Ἐπιπλέον

Ἐνέργειες Mu4e

Οἱ ἐνέργειες Mu4e καθιστοῦν πραγματικὰ ἁπλὴ τὴν ἐργασία μὲ διορθώσεις Git· αὐτὴ εἶναι ἕνα παράδειγμα διαμόρφωσης ποὺ ἴσως θέλεις νὰ χρησιμοποιήσεις:

(setf mu4e-view-actions
      (delete-dups
       (append
    '(("gapply git patches" . mu4e-action-git-apply-patch)
      ("mgit am patch" . mu4e-action-git-apply-mbox)))))

Ὑπόγραψε τὰ μηνύματα ἠλεκτρονικοῦ ταχυδρομείου σου μὲ pgp

Ἂν ἔχεις ρυθμίσει τὸ δικό σου κλειδὶ pgp, μπορεῖς νὰ ὑπογράφεις αὐτόματα ὅλα τὰ μηνύματα ἠλεκτρονικοῦ ταχυδρομείου σου μὲ αὐτὸ τὸ ἄγκιστρο:

(add-hook 'message-send-hook 'mml-secure-message-sign-pgpmime)

Ρίξε μία ματιὰ στὶς συναρτήσεις ποὺ ὁρίζονται γιὰ mml-mode-map γιὰ περισσότερα.

Τὸ Gnosis δὲν χρησιμοποιεῖ μάθηση τύπου καρτῶν μνήμης· ἀντ’ αὐτοῦ χρησιμοποιεῖ δυαδικὴ τιμὴ γιὰ νὰ ἀξιολογήσει τὴν εἴσοδο τοῦ χρήστη. Δηλαδή ἢ ξέρεις τὴ σωστὴ ἀπάντηση, ἢ δὲν τὴν ξέρεις· δὲν ἐμπλέκεται καμία δική σου βαθμολόγηση.

Περὶ

Στὸ προηγούμενό μου ἄρθρο, Παράπονα γιὰ λογισμικὸ ἐπανάληψης μὲ διαστήματα, παρουσίασα ἕνα σχέδιο γιὰ αὐτὸ ποὺ θεωρῶ βέλτιστο σχεδιασμὸ ἑνὸς SRS, ποὺ καλύπτει τὶς δικές μου προσωπικὲς προτιμήσεις.

Ἔτσι, ἀνέπτυξα τὸ δικό μου SRS, gnosis (γνῶσις), προφερόμενο «GNU-sis», ποὺ σημαίνει γνώση στὰ ἑλληνικά. Αὐτὸ τὸ SRS ἀντιμετωπίζει τὶς ἀνησυχίες ποὺ εἶχα ἐπισημάνει προηγουμένως. Πρὸς τὸ παρόν, τὸ βρῆκα ἐξαιρετικὰ ὠφέλιμο καὶ, ὡς ἐκ τούτου, ἀποφάσισα νὰ τὸ μοιραστῶ μὲ ὅλους σας.

Διαφορὲς μὲ ἄλλα SRS

Τὸ Gnosis δὲν ὑλοποιεῖ συνεδρίες ἐπανάληψης μὲ κάρτες μνήμης ὅπου ὁ χρήστης βαθμολογεῖ μόνος του τὴν ἀπάντησή του σὲ αὐθαίρετη κλίμακα. Ἀντ’ αὐτοῦ ὑλοποιεῖ τύπους «σημείωσης» ποὺ ἀπαιτοῦν εἴσοδο χρήστη. Κάποιοι ἀπὸ αὐτοὺς τοὺς τύπους σημειώσεων, ὅπως τὸ MCQ ἐρώτηση πολλαπλῆς ἐπιλογῆς, ἐπιτρέπουν ἀκόμα καὶ τὴν προσομοίωση ἐξετάσεων πραγματικῆς ζωῆς.

Σὲ ἀντίθεση μὲ ἄλλες ὑλοποιήσεις SRS γιὰ GNU Ἤμαξ, τὸ gnosis δὲν βασίζεται στὸ org-mode, ποὺ ἔχω βρεῖ ὅτι δὲν εἶναι ἰδανικὴ ἐπιλογὴ ὡς ἀντικαταστάτης βάσης δεδομένων. Ἀντ’ αὐτοῦ ἐπιλέγει βάση sqlite μὲ git γιὰ παρακολούθηση ὁποιωνδήποτε ἀλλαγῶν, ἐπιτρέποντας ἀποδοτικὴ διαχείριση δεδομένων, χειρισμὸ καὶ ἀκεραιότητα δεδομένων.

Ἐπιπλέον, ἐφόσον τὸ Gnosis βασίζεται στὸν Ἤμαξ καὶ εἶναι γραμμένο σὲ Emacs Lisp, προσφέρει βολικὴ καὶ (ἐλπίζω) εὐχάριστη ἐμπειρία προσαρμογῆς σύμφωνα μὲ τὶς ἀτομικές σου προτιμήσεις.

Ὡστόσο, ἕνα μειονέκτημα τῆς χρήσης τοῦ Gnosis εἶναι ὅτι πρὸς τὸ παρὸν δὲν ὑποστηρίζεται σὲ κινητὲς συσκευές, καθὼς ὁ Ἤμαξ δὲν ἔχει ἀκόμα ἐπεκτείνει τὴ συμβατότητά του σὲ τέτοιες πλατφόρμες.

Ἐγκατάσταση

Μπορεῖς νὰ πάρεις τὸ gnosis ἀπὸ τὸν προσωπικό μου git διακομιστὴ ἐδῶ ἢ χρησιμοποιώντας αὐτὸν τὸν ἀντίγραφο στὸ SourceHut.

Straight.el

(straight-use-package
 '(gnosis :type git
          :host nil
          :repo "https://git.thanosapollo.org/gnosis"))

Χειροκίνητα

$ git clone https://git.thanosapollo.org/gnosis

Πρόσθεσε αὐτὸ στὴ διαμόρφωση Ἤμαξ σου:

(add-to-list 'load-path "/path/to/gnosis")
(load-file "~/path/to/gnosis.el")
(require 'gnosis)

Προσθήκη σημειώσεων

Ἡ δημιουργία σημειώσεων γιὰ gnosis μπορεῖ νὰ γίνει μὲ ἁπλὸ M-x gnosis-add-note

Τὰ πάντα γίνονται μέσω τοῦ mini-buffer. Ἡ προσωπική μου ροὴ ἐργασίας ἐκμεταλλεύεται αὐτὸ μὴ φεύγοντας οὐσιαστικὰ ἀπὸ τὴν προτροπὴ gnosis-add-note μέχρι νὰ τελειώσω τὴ μελέτη ἑνὸς κεφαλαίου/τμήματος, χρησιμοποιώντας pdf-tools ἢ nov.el.

Νομίζω δὲν θὰ χρειαστεῖς πολλὴ καθοδήγηση στὴ δημιουργία σημειώσεων γιὰ ὁποιονδήποτε τύπο σημείωσης, ἐκτὸς ἀπὸ cloze.

Δημιουργία σημειώσεων τύπου cloze

Οἱ ἐρωτήσεις σημειώσεων τύπου cloze μορφοποιοῦνται παρόμοια μὲ τὴ σύνταξη τοῦ Anki, ὡς ἑξῆς: > Ἡ {c1:κυπροεπταδίνη} εἶναι {c2:ἀνταγωνιστὴς ὑποδοχέων 5-HT2} ποὺ χρησιμοποιεῖται γιὰ τὴ θεραπεία τοῦ {c2:συνδρόμου σεροτονίνης}

ΣΗΜΕΙΩΣΗ: Μπορεῖς ἐπίσης νὰ μορφοποιήσεις clozes σὰν Anki ἂν τὸ προτιμᾶς· π.χ. {{c1::Cyproheptadine}}

• Γιὰ κάθε ἐτικέτα cX θὰ δημιουργηθεῖ σημείωση τύπου cloze· τὸ παραπάνω παράδειγμα δημιουργεῖ 2 σημειώσεις τύπου cloze.

• Κάθε ἐτικέτα cX μπορεῖ νὰ ἔχει πολλαπλὰ clozes, ἀλλὰ κάθε cloze πρέπει νὰ εἶναι ΜΟΝΑΔΙΚΗ λέξη (ἢ μοναδικὸς συνδυασμὸς λέξεων) στὴ δεδομένη σημείωση.

Προσαρμογὴ ἀλγορίθμου gnosis

gnosis-algorithm-interval

Αὐτὴ εἶναι μιὰ λίστα 2 ἀριθμῶν, γιὰ τὰ πρῶτα 2 διαστήματα μετὰ ἀπὸ ἐπιτυχῆ ἐπανάληψη. Γιὰ παράδειγμα:

(setq gnosis-algorithm-interval '(1 3))

Μετὰ τὴν πρώτη ἐπιτυχῆ ἐπανάληψη μιᾶς σημείωσης, θὰ τὴ δεῖς ξανὰ αὔριο· ἂν ἐπαναλάβεις ἐπιτυχῶς τὴν ἴδια σημείωση ξανά, ἡ ἑπόμενη ἐπανάληψη θὰ εἶναι μετὰ ἀπὸ 3 μέρες.

gnosis-algorithm-ef

Αὐτὴ εἶναι ἡ τιμὴ τοῦ «παράγοντα εὐκολίας» gnosis· βασικὰ εἶναι μιὰ λίστα ποὺ ἀποτελεῖται ἀπὸ 3 στοιχεῖα. Τὸ πρῶτο στοιχεῖο εἶναι ὁ παράγοντας αὔξησης, ποὺ χρησιμοποιεῖται γιὰ νὰ αὐξήσει τὸν παράγοντα εὐκολίας μετὰ ἀπὸ ἐπιτυχῆ ἐπανάληψη. Τὸ δεύτερο στοιχεῖο ἀναφέρεται στὸν παράγοντα μείωσης, ποὺ χρησιμοποιεῖται γιὰ νὰ μειώσει τὸν παράγοντα εὐκολίας μετὰ ἀπὸ ἀποτυχημένη ἐπανάληψη. Τὸ τρίτο στοιχεῖο εἶναι ὁ (ἀρχικὸς) συνολικὸς παράγοντας εὐκολίας, ποὺ χρησιμοποιεῖται γιὰ τὸν ὑπολογισμὸ τοῦ ἑπόμενου διαστήματος.

Τὰ βασικὰ τοῦ πῶς χρησιμοποιεῖται εἶναι ὅτι πολλαπλασιάζεται μὲ τὸ τελευταῖο διάστημα· π.χ. ἂν ἐπανέλαβες τελευταία φορὰ μιὰ σημείωση πρὶν 6 μέρες, καὶ ὁ παράγοντας εὐκολίας (συνολικὸς) αὐτῆς τῆς σημείωσης εἶναι 2.0, τὸ ἑπόμενο διάστημά σου θὰ ἦταν 6 * 2.0 & ὁ ἑπόμενος συνολικὸς ef θὰ εἶναι 2.0 + increase-factor.

Παράδειγμα διαμόρφωσης:

(setq gnosis-algorithm-ef '(0.3 0.3 1.3))

gnsois-algorithm-ff

Αὐτὴ εἶναι ἡ τιμὴ τοῦ παράγοντα λήθης (ff) gnosis· πρέπει νὰ εἶναι ἀριθμὸς κινητῆς ὑποδιαστολῆς κάτω ἀπὸ 1. Χρησιμοποιεῖται γιὰ τὸν ὑπολογισμὸ τοῦ ἑπόμενου διαστήματος μετὰ ἀπὸ ἀποτυχημένη ἐπανάληψη, πολλαπλασιαζόμενη μὲ τὸ τελευταῖο διάστημα. Ἂν γιὰ μιὰ σημείωση μὲ τιμὴ last-interval 6 ἡμερῶν καὶ ff 0.5, μετὰ ἀπὸ ἀποτυχημένη ἐπανάληψη τὸ ἑπόμενο διάστημα θὰ εἶναι σὲ 6 * 0.5 μέρες

Παράδειγμα διαμόρφωσης:

(setq gnosis-algorithm-ff 0.5)

Θὰ πρέπει ἐπίσης νὰ σημειώσω ὅτι θεωρῶ τὴν ἐπανάληψη μὲ διαστήματα κόλπο γιὰ τὴ μάθηση, ποὺ θὰ ἔπρεπε νὰ χρησιμοποιεῖται ἀπὸ κάθε φοιτητή.

Τί εἶναι ἡ μάθηση μὲ ἐπανάληψη μὲ διαστήματα

Ἡ ἐπανάληψη μὲ διαστήματα βασίζεται στὴν ἑξῆς προϋπόθεση: > Ἡ ἐπαναλαμβανόμενη ἔκθεση σὲ πληροφορία συμβάλλει στὴν ἐπιμήκυνση τῆς > διατήρησης μνήμης.

Οἱ γνωστικές μας ἱκανότητες εἶναι ἐγγενῶς προγραμματισμένες νὰ διατηροῦν σχετικὴ πληροφορία ἐνῶ ἀπορρίπτουν περιττὲς λεπτομέρειες, διαδικασία ποὺ ἐξαρτᾶται ἀπὸ τὴ συχνότητα μὲ τὴν ὁποία συναντᾶμε τέτοια πληροφορία.

Σύνοψις: Ὅσο πιὸ συχνὰ ἐκτίθεσαι σὲ πληροφορία, τόσο περισσότερο τὴν διατηρεῖς

Τὰ «παράπονά» μου μὲ λογισμικὸ ἐπανάληψης μὲ διαστήματα

Ἔχω ἐπιλέξει νὰ ἀναπτύξω τὸ δικό μου SRS (λογισμικὸ/σύστημα ἐπανάληψης μὲ διαστήματα) ἀντὶ νὰ βασίζομαι σὲ ὑπάρχοντα, καθιερωμένα. Μέσω τῆς ὑλοποίησής μου μὲ ὄνομα «gnosis» (GNOH-sis, ποὺ σημαίνει γνώση στὰ ἑλληνικὰ) στοχεύω νὰ ἀντιμετωπίσω καὶ νὰ ὑπερβῶ τὶς προκλήσεις καὶ τοὺς περιορισμοὺς ποὺ συνδέονται μὲ τρέχουσες λύσεις SRS. Μὲ τὸ gnosis, ἐλπίζω νὰ ἐπιλύσω τὰ περισσότερα, ἂν ὄχι ὅλα, ἀπὸ αὐτὰ τὰ προβλήματα καὶ νὰ προσφέρω πιὸ ἐκλεπτυσμένη καὶ προηγμένη μαθησιακὴ ἐμπειρία.

Ὄχι libreware

Αὐτὸ ἀναφέρεται σὲ ἰδιόκτητα προγράμματα λογισμικοῦ ποὺ ὑλοποιοῦν ἐπανάληψη μὲ διαστήματα, μερικὰ ἀπὸ τὰ ὁποῖα εἶναι ἀκόμα καὶ ἔνοχα γιὰ ἀφαίρεση τῆς δυνατότητας ἐπανάληψης μὲ διαστήματα γιὰ τὴν ὁποία οἱ χρήστες πλήρωσαν. Εἶχα πληρωμένη συνδρομὴ μὲ τὸ quizlet μόνο γιὰ νὰ ἀνακαλύψω ὅτι ἀφαίρεσαν τὴ δυνατότητα ἐπανάληψης μὲ διαστήματα ποὺ εἶχα ἤδη πληρώσει & χρησιμοποιοῦσα, καθιστώντας τὴν τότε ροὴ ἐργασίας μου ἄχρηστη.

Μὴ βασίζεσαι σὲ λογισμικὸ ποὺ δὲν κατέχεις γιὰ τὴ δουλειά σου. Δὲν «κατέχεις» ἰδιόκτητο λογισμικό, παρὰ τὸ ὅτι πληρώνεις γι’ αὐτό.

Θὰ ἔπρεπε νὰ ἐπιδιώκεις νὰ χρησιμοποιεῖς μόνο libreware γιὰ τὴ ροὴ ἐργασίας σου.

Ἔλλειψη προσαρμογῆς

Τὸ καλὸ λογισμικὸ θὰ ἔπρεπε νὰ ταιριάζει στὴ ροὴ ἐργασίας σου σὰν γάντι· γιὰ νὰ τὸ κάνει αὐτὸ πρέπει νὰ δίνει πολὺ χῶρο γιὰ προσαρμογὴ ἀπὸ τὸν χρήστη. Ἁπλὲς ἀλλαγὲς ὅπως ἀλλαγὲς χρωματικοῦ σχήματος μέχρι πιὸ προηγμένη προσαρμογὴ χαρακτηριστικῶν ὅπως προσθήκη δικών σου τύπων καρτῶν καὶ ἀλλαγὴ τοῦ ἀλγορίθμου ἐπανάληψης μὲ διαστήματα θὰ ἔπρεπε νὰ εἶναι ἁπλὲς καὶ εὔκολες. Γιὰ παράδειγμα, ἕνας φοιτητὴς ἰατρικῆς θὰ χρησιμοποιοῦσε μεγαλύτερο χρονικὸ διάστημα γιὰ τὸν ἀλγόριθμό του ἀπὸ, ἂς ποῦμε, κάποιον ποὺ προσπαθεῖ νὰ ἐπεκτείνει τὸ ἰαπωνικό του λεξιλόγιο.

Ἀφοῦ ἤδη καθιερώσαμε τὴν ἀνάγκη τὸ ἰδανικό μας λογισμικὸ νὰ εἶναι libreware, ἡ πραγματοποίηση ἀλλαγῶν στὰ βασικὰ συστατικὰ θὰ ἦταν εὔκολη. Ἀλλὰ θὰ ἔπρεπε νὰ προστεθεῖ ὅτι ἡ προσαρμογὴ γιὰ διαφορετικὲς ἀνάγκες & στυλ μάθησης θὰ ἔπρεπε νὰ εἶναι πρωταρχικὸς στόχος κατὰ τὸν σχεδιασμὸ ἑνὸς SRS.

Οἱ κάρτες μνήμης εἶναι κατώτερη μέθοδος μάθησης.

Οἱ κάρτες μνήμης εἶναι ἀρκετὰ ἁπλὲς νὰ φτιαχτοῦν· πρωτότυπες μέθοδοι ἐπανάληψης μὲ διαστήματα χρησιμοποιοῦσαν φυσικὲς κάρτες μνήμης. Οἱ σημερινοὶ ὑπολογιστὲς μᾶς ἐπιτρέπουν πιὸ ἐξελιγμένες μεθόδους «ἐπανάληψης», ὅπως τὴ χρήση εἰσόδου χρήστη.

Ἡ χρήση εἰσόδου χρήστη γιὰ τὴν ἀξιολόγηση τῆς ἀποτελεσματικότητας μιᾶς ἐπανάληψης εἶναι προτιμότερη ἀπὸ τὸ ἁπλῶς νὰ ἀποκαλύπτεις μιὰ ἀπάντηση καὶ νὰ ρωτᾶς ἂν ἦταν γνωστὴ ἢ ὄχι. Αὐτὴ ἡ προσέγγιση ἐξασφαλίζει ὄχι μόνο τὴν κατανόηση τῆς ἀπάντησης ἀλλὰ καὶ τὴν ἀκριβῆ ὀρθογραφία της. Ἐπιπλέον, ὁδηγεῖ σὲ πιὸ ἀποδοτικὴ διατήρηση σὲ σύγκριση μὲ τὴν ἁπλὴ ἐμφάνιση τῆς ἀπάντησης χωρὶς ἐνεργὴ συμμετοχὴ τοῦ χρήστη.

Ἰδανικὰ μὲ τὸ Gnosis θὰ ἤθελα ἐπίσης νὰ ὑλοποιήσω τύπο MCQ γιὰ προσομοίωση τῶν ἐξετάσεων USMLE ποὺ ἐλπίζω σύντομα νὰ ἐξεταστῶ. Αὐτὸ θὰ καταστήσει δυνατὴ τὴν προσομοίωση ὁποιασδήποτε ἄλλης ἐξέτασης MCQ

Ὄχι αὐτοβαθμολόγηση

Συνιστᾶται οἱ χρήστες νὰ μὴν αὐτοβαθμολογοῦν τὶς ἀπαντήσεις τους. Ἡ διαδικασία ἐπανάληψης θὰ ἔπρεπε νὰ περιλαμβάνει δυαδικὴ ἀξιολόγηση ἐπιτυχίας ἢ ἀποτυχίας, ὅπου οἱ χρήστες εἴτε ἀνακαλοῦν σωστὰ τὴν ἀπάντηση εἴτε ὄχι. Αὐτὴ ἡ βαθμολογία ἐπιτυχίας/ἀποτυχίας θὰ χρησιμοποιεῖται γιὰ νὰ καθορίσει τὸ ἑπόμενο διάστημα γιὰ τὴ συγκεκριμένη σημείωση, βελτιστοποιώντας τὸ σύστημα ἐπανάληψης μὲ διαστήματα γιὰ ἀποτελεσματικὴ μάθηση.

Συνεργασία

Τὸ περισσότερο λογισμικὸ ἐπανάληψης μὲ διαστήματα βασίζεται σὲ βάσεις δεδομένων γιὰ ἀποθήκευση, ἀλλὰ τὸ μειονέκτημα εἶναι ὅτι οἱ βάσεις δεδομένων δὲν εἶναι εὔκολα ἀναγνώσιμες ἢ ἐπεξεργάσιμες ἀπὸ ἀνθρώπους, ἐμποδίζοντας τὴν κοινὴ χρήση καὶ τὴ συνεργασία.

Γιὰ νὰ ἀντιμετωπίσω αὐτὸν τὸν περιορισμό, σκοπεύω νὰ ἐνσωματώσω δυνατότητες ἐξαγωγῆς στὸ gnosis. Αὐτὴ ἡ δυνατότητα θὰ ἐπέτρεπε στοὺς χρήστες νὰ ἐξάγουν ἕνα deck σημειώσεων σὲ φιλικὴ πρὸς τὸν χρήστη μορφή, τὸ ὁποῖο οἱ χρήστες μποροῦν νὰ μοιράζονται καὶ νὰ ἐπεξεργάζονται συνεργατικὰ μὲ ἐργαλεῖα ὅπως ἀποθετήρια git.

Αὐτὴ ἡ συνεργατικὴ προσέγγιση θὰ μᾶς ἐπέτρεπε νὰ δουλεύουμε μαζί, νὰ μοιραζόμαστε, καὶ νὰ δημιουργοῦμε πολύτιμο μαθησιακὸ ὑλικὸ ποὺ μπορεῖ νὰ χρησιμοποιηθεῖ καὶ νὰ τροποποιηθεῖ ἀπὸ ὅλους τοὺς ἐμπλεκόμενους.

Συγχρονισμὸς μεταξὺ συσκευῶν

Τὸ Anki κάνει τὸν συγχρονισμὸ μεταξὺ συσκευῶν παιχνιδάκι! Ἀλλὰ γίνεται τρομερὰ ἀργὸ ἂν συγχρονίζεις νέα συσκευὴ ὅταν ἔχεις πολὺ ὑλικὸ στὸν λογαριασμό σου, συν ὅτι βασίζεσαι στοὺς διακομιστὲς τοῦ Anki γιὰ νὰ δουλεύει.

Ἀφοῦ στὸ gnosis θὰ χρησιμοποιῶ sqlite ὡς ὑλοποίηση βάσης δεδομένων, ἁπλῶς θὰ χρησιμοποιοῦσα git γιὰ νὰ κρατῶ τὴ βάση δεδομένων μου συγχρονισμένη μεταξὺ διαφορετικῶν συσκευῶν.

Gnosis

Μπορεῖς νὰ βρεῖς τὸ gnosis στὸν git διακομιστή μου ἐδῶ, διάβασε τὸ τμῆμα Περὶ γιὰ ὁδηγίες ἐγκατάστασης.

Δὲν εἶναι ἀκόμα οὔτε σὲ δοκιμαστικὴ ἔκδοση ἄλφα, ἀλλὰ διαθέτει ἤδη τὴ βασικὴ λειτουργικότητα γιὰ νὰ τὸ δοκιμάσεις. Μὴ διστάσεις νὰ μοῦ στείλεις μήνυμα ἠλεκτρονικοῦ ταχυδρομείου ἂν ἔχεις ἐρωτήσεις ἢ αἰτήματα γιὰ gnosis.

Σχετικά

Χρησιμοποιῶ τὸ eshell περισσότερο ἀπὸ κάθε ἄλλο κέλυφος τελευταῖα, ἀλλὰ ὑστερεῖ σὲ συμπληρώσεις σὲ σύγκριση μὲ ἄλλα κελύφη.

Ἔφτιαξα αὐτὸ τὸ ἁπλὸ πακέτο γιὰ νὰ προσφέρει συμπληρώσεις γιὰ ἐγκατάσταση καὶ ἀφαίρεση πακέτων μὲ τὸ yay.

Τὸ Eshell παρέχει ἀπρόσκοπτη ἐνσωμάτωση μὲ τὸ ὑπόλοιπο οἰκοσύστημα τοῦ Ἤμαξ καί, χάρη στὴν ἐνσωμάτωση μὲ τὸ Eat, δὲν ἔχει πλέον πρόβλημα μὲ ὀπτικὲς ἐντολές, μὲ τὶς ὁποῖες παλαιότερα δυσκολευόταν. Τὸ μόνο ποὺ τοῦ λείπει εἶναι ἀξιοπρεπεῖς δυνατότητες συμπλήρωσης· πιστεύω πὼς σύντομα θὰ δοῦμε περισσότερες.

Ἐγκατάσταση

Μπορεῖτε νὰ πάρετε τὸ pcomplete-yay ἀκολουθώντας τὶς ὁδηγίες στὸ git ἀποθετήριο τοῦ ἔργου.